Perl | #!/usr/bin/perl # How I use - Plutor - fb8a11be

#!/usr/bin/perl

# How I used this:
# I saved all of the MetaTalk archives linked from <http://metatalk.metafilter.com/archive.mefi>
# Then, I ran this script with all of the filenames as arguments.
# I posted the results here: <http://metatalk.metafilter.com/14744/Safety-first#444331>

use POSIX qw(strftime);

my %mval = (    January     => 0,
                February    => 1,
                March       => 2,
                April       => 3,
                May         => 4,
                June        => 5,
                July        => 6,
                August      => 7,
                September   => 8,
                October     => 9,
                November    => 10,
                December    => 11 );

my @posts;

for my $filename (@ARGV) {
    if (open(F, "<", $filename)) {
        local $/;
        my $f = <F>;
        close(F);

        my ($month, $year) = ($f =~ /<p class="copy">(\w+) (200\d) Archives \(<a href="\/archive\.mefi">all archives<\/a>\)<\/p>/);
        $year -= 1900;

        my ($day, $hour, $min);
        while ($f =~ /<div class="monthday">(\w+) (\d+)<\/div>|<span class="smallcopy">posted by <a[^>]*>[^<]*<\/a> to <a[^>]*>[^<]*<\/a> at (\d+):(\d+) ([AP]M) PST - <a href="([^"]*)"/g) {
            if ($1 and $2) {
                $day = $2;
            } elsif ($3 and $4 and $5) {
                $hour = $3;
                $min = $4;
                $hour = 0 if ($hour == 12);
                $hour += 12 if ($5 eq "PM");

                $url = $6;
                ($name) = ($url =~ /\/mefi\/(\d+)/);

                my $u = strftime('%s', 0, $min, $hour, $day, $mval{$month}, $year);
                push @posts, [ $u, $url, $name ];
            }
        }
    } else {
        warn "Could not open $filename: $!";
    }
}

@posts = sort { $b->[0] <=> $a->[0] } @posts;
my $lastpost = shift @posts;

for my $p (@posts) {
    my $diff = abs( $lastpost->[0] - $p->[0] );
    if ($diff >= 24*60*60) {
        print "<a href=\"$lastpost->[1]\">$lastpost->[2]</a> ";
        print "and <a href=\"$p->[1]\">$p->[2]</a> - ";
        printf('%d:%02d', int($diff/3600), int($diff/60)%60);
        print " apart on " . strftime('%d %b %Y', localtime($p->[0])) . "\n";
    }

    $lastpost = $p;
}